Arduinoを使ってみよう

-

今回は、小学生でもプログラミングしてロボットなどを制御できるArduinoです。
ええい！俺はコテコテの組み込み屋だ！！
などと仰る方も、プロト作成なんかには便利此上ありません。

今日は、そんなArduinoの使い方の基本についてです。



　目次：　　　　　　　　　　

　・ Arduinoとは？

　・ Arduinoのライセンス

　・ Arduinoの開発環境

　・ Arduinoのプログラミング

　・ まずは、「Hello World」

　・ LEDを点滅させる（Lチカ！）

　・ 別のシリアルも使ってみる

　・ I2Cのデバイスを使ってみる（LCD）

なお、この記事では開発用のPCには、Windows 10 (1903)
使用するArduinoボードは、Microを使っています。


Arduinoとは？

「Arduino：アルデュイーノ」と読みます。
イタリアンな感じの発音、そう思った方は正解です。

それは2005年、北イタリアのイヴレーアという街のインタラクションデザイン工科大学（IIDI）から始まりました。

5人の人物たちが学生でも気軽に使えるような安価で、かつ、簡単に使えるコントローラー、つまりワンボードマイコンを作って販売する「Arduinoプロジェクト」から始まりました。

そして、彼らは、シンプルな設計のボードだけではなく技術者ではなくても開発が可能な開発環境の開発に成功し、ハードウェア・ソフトウェアともにオープンとなものとして公開しました。

オープンで安価、簡単ということもあり、一気に普及が進み本家Arduinoからも、いくつもの種類のボードがリリースされ、それでなく、クローンやピン互換のボードなどがたくさん販売されています。（悲しいことに非公式クローンとかも沢山！）

ところで、このArduinoという名前は、プロジェクトの一人であるマッシモ・バンジーの行きつけのバールの「Bar di Re Arduino」から取られたとか？

Arduinoのライセンス


ハードウェアはオープンハードウェアで、Creative Commons Attribution Share-Alike 2.5でライセンスされています。

また、基盤の回路図も公開されています。
　→ Arduino Microの回路図はコチラ

ソフトウェアは、開発環境である Arduino IDEはGPLv2、基板上のライブラリは LGPLでライセンスされています。

商用利用時は、商業利用の形態により対応が異なるので、専門の法務関係者にご相談することをおすすめします。

参考まで、SWITCH SCIENCEのページを

以下、プロの方向けに：
ちなみにArduinoそのものを商用の製品として使うにはオススメしません。
なぜなら余計な機能がいっぱい載っていて、マイコン本来のパワーに対して余計な負荷がたくさんあるからです。

ただし、プロト作成には十分なのでマスプロ展開するわけではない場合には適しています。

小規模なお客さんはコレで満足する場合もしばしば。
そんな時は、お客様とは「プロトタイプ開発」として契約、あくまでもプロトタイプとして運用の枠内でライセンス運用してはいかがでしょうか？

Arduinoの開発環境


Arduinoのトップページのメニューから「SOFTWARE」→「DOWNLOADS」を選択します。



Windows zip file for non admin installを選択します。



寄付を求められますので、各自ご判断を。


インストールは、ダウンロードしたarduino-1.8.10-windows.zipを解答する、
だけ！

Zipファイルの中にあるarduino-1.x.x フォルダの中にarduino.exeがあるので、このファイルを実行します。

このようなウインドウが開きます。



ココでArduinoのプログラミングを行います。

IDEのバージョンアップも同様の手順で行います。

Arduinoのプログラミング

Arduinoではプログラムのことをスケッチと呼んでいます。
C言語のような書き方をしますが、下記の2つの基本的な関数が自動的に作成されます。

基本の関数：
void setup()
電源ONまたはリセットの直後に1回だけ実行されます。
使いたいピンやデバイスの初期設定を行います。

void loop()
上記のsetup()が実行されたあと繰り返し、ず～っと実行され続ける関数です。

ボードの設定
プログラミングの前に、まず、Arduino MicroをUSBマイクロケーブルでPCと接続します。
PCとArduinoをつなげるとUSBシリアルデバイスとして認識されますので、デバイスマネージャ等で確認してください。
（このPCではCOM3になっていますが使用するPC環境により変わってきます）

この記事ではArduino Microを使っていますので、
メニューから、[ツール]→[ボード]→[Arduino/Genuino Micro]を選択します。



シリアルポートを、[ツール]→[シリアルポート]でCOM3を指定します。
ちゃんと認識できるか、[ツール]→[ボード情報を取得]で確認してください、



設定したボードが確認できればOKです。

まずは、「Hello World」

Arduinoでも”Hello World”から入ってみましょう。

  1. void setup() {
  2.  
  3.   Serial.begin(115200);
  4.  
  5. }
  6.  
  7.  
  8.  
  9. void loop() {
  10.  
  11.   Serial.println("Hello World");
  12.  
  13.   delay(1000);
  14.  
  15. }

これは、シリアル出力を115200bpsに設定しています。
  1.   Serial.begin(115200);

最初に1回だけ行えばよいので、setup()の中に書いています。

そして、loop()の中では
  1.   Serial.println("Hello World");
  2.  
  3.   delay(1000);

シリアルに対してSerial.println()を使って"Hello World"の文字列を出力しています。
その後、delay()を使って1000ミリ秒待ちあわせます。
このあとは、自動的にloop()がまた呼び出されるようになっています。

このシリアルの出力はドコですか？
設定しているシリアルは、PCと接続しているUSBシリアルです。
メニューの[ツール]→[シリアルモニタ]でシリアルモニタを開いて速度を115200bpsに設定しましょう。
もちろん、このシリアルモニタでなくてもTeraTermなどでも問題ありません。

このコードをコンパイルしてボードに送るには→アイコンをクリックします。
自動的にコンパイルして、ボードへの書き込みまで行ってくれます。

「Hello World」が1秒おきに表示されましたか？

このUSBシリアルは、ArduinoがUSBからの給電で動作していることもあり、デバッグで使われることが多いです。

注意！
このシリアルが動作したままの状態では、Aruduino Microのプログラムを書き換えられません。
Arduino上のフラッシュを書き換えるとき、リセット動作を行うようにできています。
Arduino Microではこのシリアルを1200bpsでOpen/Closeすることでリセット動作がかかります。
（リセット動作は、他のArduinoでは別の動作になります。）

 このため、シリアルを受信しているターミナルソフトを閉じないと、リセット動作できずプログラムの書き換えができません。



LEDを点滅させる（Lチカ！）


では、今度は先程のプログラムに追記してボード上のLEDを点滅する機能を追加してみましょう。


  1. void setup() {
  2.   // put your setup code here, to run once:
  3.   Serial.begin(115200);
  4.   pinMode(LED_BUILTIN, OUTPUT);
  5.  
  6. }
  7.  
  8. uint8_t led = 0;
  9.  
  10. void loop() {
  11.   // put your main code here, to run repeatedly:
  12.   Serial.println("Hello World");
  13.   led = ~led;
  14.   digitalWrite(LED_BUILTIN, led);
  15.   delay(1000);
  16.  
  17. }

LEDをON/OFFするためにボード上のLEDに接続されたPINをGPIOの出力モードに設定しています。
  1.   pinMode(LED_BUILTIN, OUTPUT);

LEDのON/OFFは
  1.   digitalWrite(LED_BUILTIN, led);
で、行いますが毎回反転させたいのでledという変数を反転しています。
  1.   led = ~led;

最初の"Hello World"が出力されながら、LEDも1秒毎に点滅しています。

別のシリアルも使ってみる


USBシリアルをデバッグに使っていると、他のピンをシリアルにしたくなります。
回路図でArduino Microのピンを確認すると、J5の3がTxで4がRxです。

このシリアルは、Arduinoの中ではSerial1として認識されています。
そこで、このSerial1を9600bpsで初期化してこちらで"Hello World"を表示し、USBシリアルの方は"DEBUG"と表示しましょう。

  1. void setup() {
  2.   // put your setup code here, to run once:
  3.   Serial.begin(115200);
  4.   Serial1.begin(9600);
  5.  
  6.   pinMode(LED_BUILTIN, OUTPUT);
  7.  
  8. }
  9.  
  10. uint8_t led = 0;
  11.  
  12. void loop() {
  13.   // put your main code here, to run repeatedly:
  14.   Serial.println("DEBUG");
  15.   Serial1.println("Hello World");
  16.  
  17.   led = ~led;
  18.   digitalWrite(LED_BUILTIN, led);
  19.   delay(1000);
  20.  
  21. }

setup()でSerial1を9600bpsで初期化します。
  1.   Serial1.begin(9600);

loop()の中では、Serial1に"Hello World"を出力。
  1.   Serial1.println("Hello World");

表示するには、BeagleBone Blackの記事でも使った3.3VのUSB変換ケーブルを使います。


秋月電子で扱っているFTDIの3.3V USB変換ケーブルでは、コネクタの黄色がRXDなので、J5の3番ピンをジャンパー線などで接続します。

そしてTeraTermなどの端末ソフトで受信してください。

I2Cのデバイスを使ってみる（LCD）


ブレッドボードにArduino microを載っけたので、手元にI2CのLCDモジュールAQM1602Y-RN-GBW があったので、接続してみたくなりました。

ヨシ、やってみよう！

さて、Arduinoの回路図を確認するとI2CはJ5の7番ピンがSDA、8番ピンがSCLです。
結線は下記のようになります。



J5
3: Tx → USB変換ケーブルRXD
7: SDA → AQM1602 7 SDA
8: SCL → AQM1602 8 SCL

J6
4: GND → AQM1602 6 VSS
16: 3.3V → AQM1602 5 VDDと 9 /RES

AQM1602
2: VDDを1.0uf経由で接続
3と4を1.0uf経由で接続

※後から気が付きましたが。。。
AQM1602Yは3.3V動作、Arduinoは5V動作なので、電源は3.3Vを接続しました。
しかし、信号線も5V規定で動作するのでSDAとSCLを分圧するか、レベルシフタを入れて5V←→3.3V変換してやったほうがよいです。
データシートを確認するとVDDは4.5VがMax、SDA/SCLのMAXはVDDとありますが、実際にオシロで確認すると、SDA/SCLとも3.9Vくらいあり、VDD以上の電圧が入っていました。デバイスの実力で動いている状態です。

 　レベルシフタを入れる、或いは、AQM1602XA-RN-GBWなどの5V動作を保証するデバイスを利用することをオススメします。

実際の状況はこんな感じ。




ArduinoでI2Cを使うには？
実は、Arduinoの基本部分のソフトウェアにはI2Cの機能が入っていません。
Arduinoでは拡張的な機能はライブラリとして提供されています。I2Cは"Wire Libraly"として利用することができます。

外部のライブラリを使うには、そのライブラリのヘッダファイルをインクルードする必要があります。

コードの先頭に下記のコードを追記します。
  1. #include <Wire.h>

これで、Wireライブラリが使えるようになりました。

ではI2Cを初期化するために、setup()に下記のコードを追記します。
  1.   Wire.begin();             // I2C有効

これだけで、I2C自体は使えるようになりました。

LCDモジュールは初期化しなくては使えない！
電源投入後、LCDモジュールを初期化するための呪文が必要です。

詳細は、AQM1602Y-RN-GBWのデータシート（秋月電子）を！

初期化シーケンス
電源投入後40ミリ秒待ってから、
コマンドで0x38、0x39、0x14、0x73、0x56、0x6Cを送り、

200ミリ秒待って、
0x38、0x0C、0x01を送って、

1ミリ秒待てばOK

デバイスのスレーブアドレスは0x3E
です。
データシートによるとコントロールバイトに続いてデータバイトを送ります。
このコントロールバイトで続くデータバイトがLCDモジュールの制御コマンドなのか表示データなのかを指定します。
具体的にはコントロールバイトのRSビット0x40が0のときコマンド、1のときデータとなります。

いきなりコーディングを始めると、プログラムが長～くなってしまうので、今回は関数化します。

まずは、コマンド送信関数
  1. void sendCommand(uint8_t cmd) {
  2.  
  3.   Wire.beginTransmission(AQM1602);
  4.   Wire.write(0x00);
  5.   Wire.write(cmd);
  6.   Wire.endTransmission();
  7.  
  8.   return;
  9. }

指定したスレーブアドレスに対して通信を開始します。
  1.   Wire.beginTransmission(AQM1602);

AQM1602はconstで0x3Eとしています。
  1. const uint8_t AQM1602 = 0x3E;

write()でバイトを送信します。コントロールバイトに0x00を送って続くデータバイトがコマンドであることを示します。
  1.   Wire.write(0x00);
  2.   Wire.write(cmd);

最後に、通信完了とします。
  1.   Wire.endTransmission();


同様に、データの出力関数も作成しておきましょう。
  1. void sendData(uint8_t data) {
  2.  
  3.   Wire.beginTransmission(AQM1602);
  4.   Wire.write(0x40);
  5.   Wire.write(data);
  6.   Wire.endTransmission();
  7.  
  8.   return;
  9. }


さて、これらの関数を元に簡単なタイマーを作ってみましょう。

以下、全ソースコード（完成品）

  1. /*!
  2.  * Copyright <2020> <lightning Brains>
  3.  *
  4.  * Permission is hereby granted, free of charge, to any person obtaining a copy of this software and
  5.  * associated documentation files (the "Software"), to deal in the Software without restriction,
  6.  * including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense,
  7.  * and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do
  8.  * so, subject to the following conditions:
  9.  *
  10.  * The above copyright notice and this permission notice shall be included in all copies or substantial
  11.  * portions of the Software.
  12.  *
  13.  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED,
  14.  * INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A
  15.  * PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR 
  16.  * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  17.  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
  18.  * WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  19.  */
  20.  
  21. #include <Wire.h>
  22.  
  23.  
  24. // Const
  25. const char LIGHTNING_BRAINS[] = {"LightningBrains"};
  26. const uint8_t AQM1602 = 0x3E;
  27.  
  28. // Global
  29. uint8_t led = 0;
  30. int hh = 0;
  31. int mm = 0;
  32. int ss = 0;
  33.  
  34.  
  35. /*
  36.  * sendCommand(uint8_t cmd)
  37.  *   AQM1602 Command data send
  38.  *
  39.  *   cmd: command data
  40.  */
  41. void sendCommand(uint8_t cmd) {
  42.  
  43.   Wire.beginTransmission(AQM1602);
  44.   Wire.write(0x00);
  45.   Wire.write(cmd);
  46.   Wire.endTransmission();
  47.  
  48.   return;
  49. }
  50.  
  51.  
  52. /*
  53.  * sendData(uint8_t data)
  54.  *   AQM1602 Display data send
  55.  *
  56.  *   data: display character code
  57.  */
  58. void sendData(uint8_t data) {
  59.  
  60.   Wire.beginTransmission(AQM1602);
  61.   Wire.write(0x40);
  62.   Wire.write(data);
  63.   Wire.endTransmission();
  64.  
  65.   return;
  66. }
  67.  
  68.  
  69. /*
  70.  * clearLCD()
  71.  *   Clear the screen of AQM1602
  72.  */
  73. void clearLCD() {
  74.  
  75.   sendCommand(0x38);
  76.   sendCommand(0x0C);
  77.   sendCommand(0x01);
  78.   delay(1);
  79.  
  80.   return;
  81. }
  82.  
  83.  
  84. /*
  85.  * initLCD()
  86.  *   Initialize AQM1602 LCD module
  87.  */
  88. void initLCD() {
  89.  
  90.   delay(40);          // 40ミリ秒待つ
  91.   sendCommand(0x38);
  92.   sendCommand(0x39);
  93.   sendCommand(0x14);
  94.   sendCommand(0x73);
  95.   sendCommand(0x56);
  96.   sendCommand(0x6C);
  97.   delay(200);         // 200ミリ秒待つ
  98.  
  99.   clearLCD();         // Clear screen
  100.  
  101.   return;
  102. }
  103.  
  104.  
  105. /*
  106.  * sendText(char* txt, int size)
  107.  *   Text send to AQM1602 screen
  108.  *
  109.  *   txt: display text
  110.  *   size: text length
  111.  */
  112. int sendText(char* txt, int size) {
  113.  
  114.   int sent = 0;
  115.  
  116.   // 全てのデータを1バイトづつ出力
  117.   for(sent = 0; sent < size; sent ++) {
  118.     sendData((uint8_t)*(txt +sent));
  119.   }
  120.  
  121.   return sent;
  122. }
  123.  
  124.  
  125. /*
  126.  * setCursor(int x, int y)
  127.  *   Set display location in AQM1602 screen
  128.  *
  129.  *   x: X position, 0-15
  130.  *   y: Y position, 0-1
  131.  */
  132. bool setCursor(int x, int y) {
  133.  
  134.   uint8_t cursor = 0x80;    // Set DDRAM Address command
  135.  
  136.   if(x > 15)                // 16桁
  137.     return false;
  138.   if(y > 1)                 // 2行
  139.     return false;
  140.  
  141.   // 下位7ビットにDDRAMアドレスを設定
  142.   cursor |= x;
  143.   if(y) {
  144.     cursor |= 0x40;
  145.   }
  146.  
  147.   sendCommand(cursor);      // コマンド送信
  148.  
  149.   return true;
  150. }
  151.  
  152.  
  153. void setup() {
  154.   // put your setup code here, to run once:
  155.   Serial.begin(115200);     // USBシリアル
  156.   Serial1.begin(9600);      // J5-3/4
  157.  
  158.   pinMode(LED_BUILTIN, OUTPUT); // ボード上のLED出力有効
  159.  
  160.   Wire.begin();             // I2C有効
  161.   initLCD();                // AQM1602初期化
  162.  
  163.   setCursor(1, 0);          // 表示位置 1, 0
  164.   sendText(LIGHTNING_BRAINS, strlen(LIGHTNING_BRAINS));
  165.  
  166. }
  167.  
  168.  
  169. void loop() {
  170.   // put your main code here, to run repeatedly:
  171.   // シリアル出力
  172.   Serial.println("DEBUG");
  173.   Serial1.println(LIGHTNING_BRAINS);
  174.  
  175.   // LED反転
  176.   led = ~led;
  177.   digitalWrite(LED_BUILTIN, led);
  178.  
  179.   char  buf[18];            // 表示バッファ
  180.  
  181.   // 経過時刻表示
  182.   sprintf(buf, "%02d:%02d:%02d", hh, mm, ss);
  183.   setCursor(4, 1);
  184.   sendText(buf, strlen(buf));
  185.  
  186.   // 経過時刻更新
  187.   ++ss;
  188.   if(ss > 59) {
  189.     ss = 0;
  190.     ++mm;
  191.     if(mm > 59) {
  192.       mm = 0;
  193.       ++hh;
  194.       if(hh > 23)
  195.         hh = 0;
  196.     }
  197.   }
  198.  
  199.   delay(1000);              // 1秒待つ
  200.  
  201. }


プログラムの説明：

LCDモジュールの初期化
void initLCD()
　前述の初期化呪文を唱えます。

LCDの表示クリア
void clearLCD()
　表示をクリアしたいときに使います。

カーソル位置を設定します。
bool setCursor(int x, int y)
　文字を表示したい位置にカーソルを移動します。

テキストを表示します。
int sendText(char* txt, int size)
　テキスト文字列をまとめて表示します。
　文字列のポインタと長さを指定します。


このコードはリセット後（または電源投入後）からの経過時間をひたすら表示します。
23:59:59を超えるとリセットされます。

ボタンとかを追加すれば、ストップウォッチなど簡単に実装できそうですね。





Have a Happy Hucking!!

 Lightning Brains

コメント

コメントを投稿

このブログの人気の投稿

Linuxシステムコール、メッセージキューの使い方

-
UNIX / Linux システムコール・プログラミング プロセス間通信(IPC)、メッセージキュー メッセージキューとは？ いわゆるメッセージボックスのような動作を行う IPC です。 プロセス間で一意に識別できるメッセージキューに対してメッセージを書き込み、受け取りができます。 また、メッセージキューは SYSTEM V IPC です。 メッセージキューを使うためには、まずメッセージキューを作成してユニークなキューIDを作成する必要があります。msgget()というシステムコールでキューを作成します。 メッセージを送信するためには msgsnd()、メッセージを受信するためには msgrcv()、最後にメッセージキューを削除するために msgctl() を使います。 メッセージの受信側プロセスのサンプルコードを下記に示します。 #include <sys/types.h> #include <stdio.h> #include <sys/ipc.h> #include <sys/msg.h> #include <string.h> #include <unistd.h> #define MSGBUFSIZ 256 int main(int argc, char** argv) { int msqid; key_t msgkey; struct msgbuf{ long mtype; char mdata[MSGBUFSIZ]; }; struct msgbuf msgdata,*p; p = &msgdata; // Make Message queue key. msgkey = ftok("msgq.key",'X'); // Get Message queue ID. msqid = msgget(msgkey,IPC_CREAT|0666); // Message receive loop wile get "Quit" massage. while(1) { // Receive a Message. ...
続きを読む

Linuxシステムコール、共有メモリの使い方

-
UNIX / Linux システムコール・プログラミング プロセス間通信(IPC)、共有メモリ 共有メモリとは？ カーネルが管理するメモリ空間をユーザープロセスに ”見えるようにする” ことで、複数のプロセス間で同じメモリ空間を利用することができます。 プロセスからは通常のメモリと同様に見えるため、同じエリアに対しての同時書き込みなどについては、排他制御を行う、あるいはアトミックな操作とするなどの対応が必要になります。 共有メモリは SYSTEM V IPC です。 それでは、早速サンプルコードについて解説します。 今回のコードは2つのプログラムで構成されています。 shm_r.c 共有メモリは、shmget()システムコールにより共有メモリを取得します。このときの引数の指定で”ない場合は作成する”、パーミッションを与えるなどの指定を行います。生成された共有メモリにアクセスするため、shmat()システムコールでポインタを得るます。 以降、このプロセスはshmat()システムコールで得たポインタを通じ、自由に共有メモリにアクセスすることができます。 この、サンプルshm_r.cは、共有メモリを生成・アタッチすると１秒毎にメモリの更新をチェックし、更新された場合は内容を表示します。このときの更新内容が "Quit"であった場合、共有メモリをデタッチし、共有メモリを破棄します。 #include <stdio.h> #include <stdlib.h> #include <string.h> #include <sys/types.h> #include <sys/ipc.h> #include <sys/shm.h> #include <unistd.h> #define DATA_SIZE 2048 int main(void) { int id; char *shmData; char data[DATA_SIZE]; // Shared memory create a new with IPC_CREATE if((id = shmget(IPC_PRIVATE, DA...
続きを読む

Linuxシステムコール、セマフォの使い方

-
イメージ
UNIX / Linux システムコール・プログラミング プロセス間通信(IPC)、セマフォ セマフォとは？ セマフォ、聞き慣れない言葉ですが大昔の鉄道の信号機のことです。 単線区間で列車同士が衝突しないようにするため、信号機が使われました。 意味合い的には同様で、コンピューター内のある資源（メモリなど）に別々のプロセスが同時にアクセスしないようにするために利用します。 セマフォはSYSTEM V IPC です。 この、セマフォを利用することで複数のプロセスが同期して処理を進めることができます。 Linuxのセマフォは、セマフォ集合として生成して利用します。 このため、1つのセマフォ集合に複数のセマフォを含めることができ、Linuxのセマフォはカウンティングセマフォであるため、複数の許可を与えることも可能です。 ただし、この記事のサンプルコードは1つの集合に1つだけのセマフォ、許可数は1つだけとなっています。 まず、セマフォ生成のサンプルコードを示します。 seminit.c #include <sys/types.h> #include <sys/ipc.h> #include <sys/sem.h> #include <stdio.h> #include <stdlib.h> union semun { int val; struct semid_ds *buf; unsigned short *array; }; int main() { key_t key; int semid; union semun arg; if ((key = ftok("sem.dat", 'S')) == -1) { perror("ftok"); exit(1); } /* create a semaphore set with 1 semaphore: */ if ((semid = semget(key, 1, 0666 | IPC_CREAT)) == -1) { p...
続きを読む